; In NetLogo, a 'breed' is teh equivalent to a class or type of agent.
; In this model, agents are individualstates, each adapting their portfolio of 
; military capabilites based on the replicator equation.

breed
[
  states 
  state 
]


; Each state possess the attributes below...
; Agent variables are denoted by the prefix "my." so that they are not confused with
; temporary variables used in particualr methods or global variables

states-own
[
  my.id                               ; an identificaiton number
  my.rocks                            ; a percentage of rocks in their miltiary portfolio
  my.papers                           ; a percentage of papers in their military portfolio
  my.scissors                         ; a percentage of scissors in their military portfolio
  my.next.rocks                       ; the percentage of rocks they will have in the next time step
  my.next.papers                      ; the percentage of papers they will have in the next time step
  my.next.scissors                    ; the percetnage of scissors they will have in then next time step
  my.color                            ; the default color of the state assign randomly during setup
]

; Global veriables are denoted by the prefix "g." to avoid confusion with temporary variables or those
; belonging to particular agents

globals
[
  g.total.rocks                       ; the total rocks in the system
  g.total.papers                      ; the total papers in the system
  g.total.scissors                    ; the total scissors in the system
  g.total.capabilities                ; the sum of all rocks, papers, and scissors in the system
  g.percentage.rocks                  ; the percentage of total capabilities that are rocks
  g.percentage.papers                 ; the percentage of total capabilities that are papers
  g.percentage.scissors               ; the percentage of total capabilities that are scissors
  g.state.id                          ; a counter for assigning ids to each state agent during setup
  
  g.mathematical.percent.rocks        ; the percentage of rocks the mathematical model predicts given the initial conditions
  g.mathematical.percent.papers       ; the percentage of papers the mathematical model predicts given the initial conditions
  g.mathematical.percent.scissors     ; the percentage of scissors the mathematical model predicts given the initial conditions
  
  g.r.r.payoff                        ; the payoff for playing rock against rock
  g.r.p.payoff                        ; the payoff for playing rock against paper
  g.r.s.payoff                        ; the payoff for playing rock against scissors
  g.p.r.payoff                        ; the payoff for playing paper against rock
  g.p.p.payoff                        ; the payoff for playing paper against paper
  g.p.s.payoff                        ; the payoff for playing paper against scissors
  g.s.r.payoff                        ; the payoff for playing scissors against rock
  g.s.p.payoff                        ; the payoff for playing scissors against paper
  g.s.s.payoff                        ; the payoff for playing scissors against scissors
  g.rock.payoff                       ; the estimated value of playing the rock strategy given a popultion of opponents
  g.paper.payoff                      ; the estimated value of playing the paper strategy given a population of opponents
  g.scissor.payoff                    ; the estimated value of playing the scissors strategy given a population of opponents
  g.initial.fitness                   ; the initial fitness of a state prior to modification based on it strategy
  g.average.fitness                   ; the average fitness of states based on their strategies
  g.rock.fitness                      ; the computed fitness of states that play the rock strategy
  g.paper.fitness                     ; the computed fitness of states that play the paper strategy
  g.scissor.fitness                   ; the computed fitness of states that play the scissors strategy
]


;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;
;                   SETUP
;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;


; Setup the simulation.  This generates a population based on the total number of "patches" in the world, 
; assigning each a random portfolio of rocks, papers, and scissors, normalized by percentage (thus always summing to 1.0).
; Each state is given a random color, but can recolored on the landscape based on their particular military capabilities.

to setup
  ca
  setup.states
  setup.globals
  update.plots
  tick
end

; Ask each "patch" to create a state agent on it, and the initialize each newly created state

to setup.states
  set-default-shape states "square"
  set g.state.id 0
  ask patches
  [
    sprout-states 1
    [
      setup.state
    ] 
  ]
  color.update.states
end


; For each state being created, assign it an id, a random strategy, and a random color

to setup.state
  set my.id g.state.id
  set g.state.id g.state.id + 1
  set my.rocks 0
  set my.papers 0
  set my.scissors 0
  set my.next.rocks 0
  set my.next.papers 0
  set my.next.scissors 0
  state.set.random.strategy
  
  let _red random 255
  let _blue random 255
  let _green random 255
  let _colors []
  set _colors fput _green _colors
  set _colors fput _blue _colors
  set _colors fput _red _colors
  set my.color _colors
  set color my.color
end

; After creating the states, initialize the global, population level variables.
; The mathematical variables will be initialized and used for comparision against the
; actions of the individual agents.

to setup.globals
  update.globals
  set g.mathematical.percent.rocks g.percentage.rocks
  set g.mathematical.percent.papers g.percentage.papers
  set g.mathematical.percent.scissors g.percentage.scissors
  
  set g.r.r.payoff 2
  set g.r.p.payoff -2
  set g.r.s.payoff 2
  set g.p.r.payoff 2
  set g.p.p.payoff 2
  set g.p.s.payoff -2
  set g.s.r.payoff -2
  set g.s.p.payoff 2
  set g.s.s.payoff 2
  set g.rock.payoff 0
  set g.paper.payoff 0
  set g.scissor.payoff 0
  set g.initial.fitness 5
  set g.average.fitness 0
  set g.rock.fitness 0
  set g.paper.fitness 0
  set g.scissor.fitness 0
  
  update.mathematical.model
end


;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;
;                   STEP
;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;


to step
  update.globals
  update.mathematical.model
  states.update.strategies
  update.plots
  tick
end


;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;
;                   GLOBALS
;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;


; examine the current population and update the global variables used for plotting purposes

to update.globals
  set g.total.rocks sum [my.rocks] of states
  set g.total.papers sum [my.papers] of states
  set g.total.scissors sum [my.scissors] of states
  set g.percentage.rocks g.total.rocks / (g.total.rocks + g.total.papers + g.total.scissors)
  set g.percentage.papers g.total.papers / (g.total.rocks + g.total.papers + g.total.scissors)
  set g.percentage.scissors g.total.scissors / (g.total.rocks + g.total.papers + g.total.scissors)
  set g.total.capabilities g.total.rocks + g.total.papers + g.total.scissors
end


to update.mathematical.model
  
  ; Solve the replicator equation based on the model's initial conditions.  The conditions are established initially at setup
  ; and then propagated each time step.
  
  set g.rock.payoff g.mathematical.percent.rocks * g.r.r.payoff + g.mathematical.percent.papers * g.r.p.payoff + 
    g.mathematical.percent.scissors * g.r.s.payoff
  set g.paper.payoff g.mathematical.percent.rocks * g.p.r.payoff + g.mathematical.percent.papers * g.p.p.payoff + 
    g.mathematical.percent.scissors * g.p.s.payoff
  set g.scissor.payoff g.mathematical.percent.rocks * g.s.r.payoff + g.mathematical.percent.papers * g.s.p.payoff +
    g.mathematical.percent.scissors * g.s.s.payoff
  
  set g.rock.fitness g.initial.fitness + g.rock.payoff
  set g.paper.fitness g.initial.fitness + g.paper.payoff
  set g.scissor.fitness g.initial.fitness + g.scissor.payoff
  
  if g.rock.fitness <= 0 or g.paper.fitness <= 0 or g.scissor.fitness <= 0
  [
    let _fitnesses []
    set _fitnesses fput g.scissor.fitness _fitnesses
    set _fitnesses fput g.paper.fitness _fitnesses
    set _fitnesses fput g.rock.fitness _fitnesses
    let _min min _fitnesses
    set g.initial.fitness ((_min * -1) + 0.1)
    
    set g.rock.fitness g.initial.fitness + g.rock.payoff
    set g.paper.fitness g.initial.fitness + g.paper.payoff
    set g.scissor.fitness g.initial.fitness + g.scissor.payoff
    
  ]
  
  set g.average.fitness g.mathematical.percent.rocks * g.rock.fitness + g.mathematical.percent.papers * g.paper.fitness + 
    g.mathematical.percent.scissors * g.scissor.fitness
  
  set g.mathematical.percent.rocks g.mathematical.percent.rocks * g.rock.fitness / g.average.fitness
  set g.mathematical.percent.papers g.mathematical.percent.papers * g.paper.fitness / g.average.fitness
  set g.mathematical.percent.scissors g.mathematical.percent.scissors * g.scissor.fitness / g.average.fitness
end


;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;
;                   STATE
;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;


to states.update.strategies
  states.update.next.strategy
  states.set.next.strategy
end


to states.update.next.strategy
  ask states
  [
    state.update.next.strategy 
  ]
end


to state.update.next.strategy
  
  ; Each state plays the replicator equation based on it's unique view of the popualtion.
  ; Agents view the population as if they were invading it, thus they do not count their own strategy
  ; when evaluating the population as a whole.  Thus, each sees the population from a different perspective.
  
  let _other.rocks sum [my.rocks] of other states
  let _other.papers sum [my.papers] of other states
  let _other.scissors sum [my.scissors] of other states
  let _total.capabilities _other.rocks + _other.papers + _other.scissors
  
  let _prob.encounter.rock _other.rocks / _total.capabilities
  let _prob.encounter.paper _other.papers / _total.capabilities
  let _prob.encounter.scissors 1.0 - (_prob.encounter.rock + _prob.encounter.paper)
  
  let _rock.payoff _prob.encounter.rock * g.r.r.payoff + _prob.encounter.paper * g.r.p.payoff + 
    _prob.encounter.scissors * g.r.s.payoff
  let _paper.payoff _prob.encounter.rock * g.p.r.payoff + _prob.encounter.paper * g.p.p.payoff + 
    _prob.encounter.scissors * g.p.s.payoff
  let _scissor.payoff _prob.encounter.rock * g.s.r.payoff + _prob.encounter.paper * g.s.p.payoff + 
    _prob.encounter.scissors * g.s.s.payoff
  
  let _initial.fitness g.initial.fitness
  
  if _initial.fitness + _rock.payoff + _paper.payoff + _scissor.payoff <= 0
  [
    set _initial.fitness (_rock.payoff + _paper.payoff + _scissor.payoff - 0.1) * -1
  ]
  
  let _rock.fitness _initial.fitness + _rock.payoff
  let _paper.fitness _initial.fitness + _paper.payoff
  let _scissor.fitness _initial.fitness + _scissor.payoff
  
  let _average.fitness _prob.encounter.rock * _rock.fitness + _prob.encounter.paper * _paper.fitness +
    _prob.encounter.scissors * _scissor.fitness
    
  set my.next.rocks my.rocks * _rock.fitness / _average.fitness
  if my.next.rocks < 0
  [
    set my.next.rocks 0 
  ]
  set my.next.papers my.papers * _paper.fitness / _average.fitness
  if my.next.papers < 0
  [
    set my.next.papers 0 
  ]
  set my.next.scissors my.scissors * _scissor.fitness / _average.fitness
  if my.next.scissors < 0
  [
    set my.next.scissors 0
  ]
  
end


to states.set.next.strategy
  ask states
  [
    set my.rocks my.next.rocks
    set my.papers my.next.papers
    set my.scissors my.next.scissors 
  ]
end


to state.set.random.strategy
  let _rocks random-float 1.0
  let _papers random-float 1.0
  let _scissors random-float 1.0
  
  let _total _rocks + _papers + _scissors
  set my.rocks _rocks / _total
  set my.papers _papers / _total
  set my.scissors 1.0 - (my.rocks + my.papers)
end


;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;
;                   PLOTS
;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;


to update.plots
  update.strategy.counts.plot
  update.mathematical.baseline.plot
  update.differences.plots
end


to update.strategy.counts.plot
  set-current-plot "strategy percentages"
  set-current-plot-pen "Rocks"
  plot g.percentage.rocks
  set-current-plot-pen "Papers"
  plot g.percentage.papers
  set-current-plot-pen "Scissors"
  plot g.percentage.scissors
end


to update.mathematical.baseline.plot
  set-current-plot "mathematical baseline"
  set-current-plot-pen "Rocks"
  plot g.mathematical.percent.rocks
  set-current-plot-pen "Papers"
  plot g.mathematical.percent.papers
  set-current-plot-pen "Scissors"
  plot g.mathematical.percent.scissors
  
end


to update.differences.plots
  set-current-plot "Rocks Difference"
  set-current-plot-pen "Agent"
  plot g.percentage.rocks
  set-current-plot-pen "Mathematical"
  plot g.mathematical.percent.rocks
  
  set-current-plot "Papers Difference"
  set-current-plot-pen "Agent"
  plot g.percentage.papers
  set-current-plot-pen "Mathematical"
  plot g.mathematical.percent.papers
  
  set-current-plot "Scissors Difference"
  set-current-plot-pen "Agent"
  plot g.percentage.scissors
  set-current-plot-pen "Mathematical"
  plot g.mathematical.percent.scissors
end


;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;;
;;      COLORING PATCHES
;;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;

; requires chooser with the following
; "default"
; "rock scale"
; "paper scale"
; "scissor scale"
; "rock scale normalized"
; "paper scale normalized"
; "scissor scale normalized"
; "majority"
;

to color.update.states
  if color.map = "default"
  [
    ask states
    [
      set color my.color
      let _color color
    ] 
  ]
  
  if color.map = "rock scale"
  [
    ask states
    [
      set color scale-color red my.rocks 0 1.0
      let _color color
    ]
  ]
  
  if color.map = "paper scale"
  [
    ask states
    [
      set color scale-color green my.papers 0 1.0
      let _color color
    ]
  ]
  
  if color.map = "scissor scale"
  [
    ask states
    [
      set color scale-color blue my.scissors 0 1.0
      let _color color
    ]
  ]
  
  if color.map = "rock scale normalized"
  [
    ask states
    [
      set color scale-color red my.rocks 0 max [my.rocks] of states
      let _color color
    ]
  ]
  
  if color.map = "paper scale normalized"
  [
    ask states
    [
      set color scale-color green my.papers 0 max [my.papers] of states
      let _color color
    ]
  ]
  
  if color.map = "scissor scale normalized"
  [
    ask states
    [
      set color scale-color blue my.scissors 0 max [my.scissors] of states
      let _color color
    ]
  ]
  
  
  if color.map = "majority"
  [
    ask states
    [
      if my.rocks > my.papers and my.rocks > my.scissors
      [
        set color red
      ]
      if my.papers > my.rocks and my.papers > my.scissors
      [
        set color green
      ]
      if my.scissors > my.papers and my.scissors > my.rocks
      [
        set color blue
      ]
    ]
  ]
end

@#$#@#$#@
GRAPHICS-WINDOW
445
10
878
464
-1
-1
14.1
1
10
1
1
1
0
1
1
1
0
29
0
29
1
1
1
ticks

BUTTON
12
12
75
45
NIL
setup
NIL
1
T
OBSERVER
NIL
NIL
NIL
NIL

BUTTON
87
12
150
45
step
step
NIL
1
T
OBSERVER
NIL
NIL
NIL
NIL

BUTTON
161
12
224
45
go
step
T
1
T
OBSERVER
NIL
NIL
NIL
NIL

PLOT
3
472
444
668
strategy percentages
NIL
NIL
0.0
10.0
0.0
1.0
true
true
PENS
"Rocks" 1.0 0 -2674135 true
"Papers" 1.0 0 -10899396 true
"Scissors" 1.0 0 -13345367 true

PLOT
3
670
446
845
mathematical baseline
NIL
NIL
0.0
10.0
0.0
1.0
true
true
PENS
"Rocks" 1.0 0 -2674135 true
"Papers" 1.0 0 -10899396 true
"Scissors" 1.0 0 -13345367 true

CHOOSER
258
11
437
56
color.map
color.map
"default" "rock scale" "paper scale" "scissor scale" "rock scale normalized" "paper scale normalized" "scissor scale normalized" "majority"
7

BUTTON
258
61
437
94
update map colors
color.update.states
NIL
1
T
OBSERVER
NIL
NIL
NIL
NIL

TEXTBOX
258
105
436
371
When color.map has selected anything but \"default\":\n\nred means \"Rocks\"\ngreen means \"Papers\"\nBlue means \"Scissors\"\n\nThe intensity of the color may be displayed based on the 0 - 100% scale, or normalized, with the state with the maximum percentage with a given strategy the brightest, and black meaning 0%.\n\nIf \"majority\" is selected, then the color denotes the strategy with the highest percetage in the portfolio.
11
0.0
1

PLOT
447
473
884
593
rocks difference
NIL
NIL
0.0
10.0
0.0
1.0
true
true
PENS
"Agent" 1.0 0 -2674135 true
"Mathematical" 1.0 0 -7500403 true

PLOT
448
599
884
719
papers difference
NIL
NIL
0.0
10.0
0.0
1.0
true
true
PENS
"Agent" 1.0 0 -10899396 true
"Mathematical" 1.0 0 -7500403 true

PLOT
449
724
886
844
scissors difference
NIL
NIL
0.0
10.0
0.0
1.0
true
true
PENS
"Agent" 1.0 0 -13345367 true
"Mathematical" 1.0 0 -7500403 true

@#$#@#$#@
WHAT IS IT?
-----------
This is a very simple implementation of the Rock Paper Scissors (RPS) and the Replicator Equation as a mathematical and agent-based model, where the agents are referred to as "states" as future developments will regard their portfolio of Rocks, Papers, and Scissors as military capabilities.


HOW IT WORKS
------------
Simply press "Setup" and "Go" to run the model.  Payoffs of different interactions, e.g. rock plays paper, can be set under the setup.globals procedure on the "Procedures".  In this case, populations of agents are generated at random, with the number of agents being equivalent to the number of patches.  Each agent implements the replicator equation is its adaptive strategy, where it adjusts its portfolio of rocks, papers, and scissors to its observation of the population.


CREDITS AND REFERENCES
----------------------
Aaron Frank
www.aaronbfrank.com
contact@aaronbfrank.com

@#$#@#$#@
default
true
0
Polygon -7500403 true true 150 5 40 250 150 205 260 250

airplane
true
0
Polygon -7500403 true true 150 0 135 15 120 60 120 105 15 165 15 195 120 180 135 240 105 270 120 285 150 270 180 285 210 270 165 240 180 180 285 195 285 165 180 105 180 60 165 15

arrow
true
0
Polygon -7500403 true true 150 0 0 150 105 150 105 293 195 293 195 150 300 150

box
false
0
Polygon -7500403 true true 150 285 285 225 285 75 150 135
Polygon -7500403 true true 150 135 15 75 150 15 285 75
Polygon -7500403 true true 15 75 15 225 150 285 150 135
Line -16777216 false 150 285 150 135
Line -16777216 false 150 135 15 75
Line -16777216 false 150 135 285 75

bug
true
0
Circle -7500403 true true 96 182 108
Circle -7500403 true true 110 127 80
Circle -7500403 true true 110 75 80
Line -7500403 true 150 100 80 30
Line -7500403 true 150 100 220 30

butterfly
true
0
Polygon -7500403 true true 150 165 209 199 225 225 225 255 195 270 165 255 150 240
Polygon -7500403 true true 150 165 89 198 75 225 75 255 105 270 135 255 150 240
Polygon -7500403 true true 139 148 100 105 55 90 25 90 10 105 10 135 25 180 40 195 85 194 139 163
Polygon -7500403 true true 162 150 200 105 245 90 275 90 290 105 290 135 275 180 260 195 215 195 162 165
Polygon -16777216 true false 150 255 135 225 120 150 135 120 150 105 165 120 180 150 165 225
Circle -16777216 true false 135 90 30
Line -16777216 false 150 105 195 60
Line -16777216 false 150 105 105 60

car
false
0
Polygon -7500403 true true 300 180 279 164 261 144 240 135 226 132 213 106 203 84 185 63 159 50 135 50 75 60 0 150 0 165 0 225 300 225 300 180
Circle -16777216 true false 180 180 90
Circle -16777216 true false 30 180 90
Polygon -16777216 true false 162 80 132 78 134 135 209 135 194 105 189 96 180 89
Circle -7500403 true true 47 195 58
Circle -7500403 true true 195 195 58

circle
false
0
Circle -7500403 true true 0 0 300

circle 2
false
0
Circle -7500403 true true 0 0 300
Circle -16777216 true false 30 30 240

cow
false
0
Polygon -7500403 true true 200 193 197 249 179 249 177 196 166 187 140 189 93 191 78 179 72 211 49 209 48 181 37 149 25 120 25 89 45 72 103 84 179 75 198 76 252 64 272 81 293 103 285 121 255 121 242 118 224 167
Polygon -7500403 true true 73 210 86 251 62 249 48 208
Polygon -7500403 true true 25 114 16 195 9 204 23 213 25 200 39 123

cylinder
false
0
Circle -7500403 true true 0 0 300

dot
false
0
Circle -7500403 true true 90 90 120

face happy
false
0
Circle -7500403 true true 8 8 285
Circle -16777216 true false 60 75 60
Circle -16777216 true false 180 75 60
Polygon -16777216 true false 150 255 90 239 62 213 47 191 67 179 90 203 109 218 150 225 192 218 210 203 227 181 251 194 236 217 212 240

face neutral
false
0
Circle -7500403 true true 8 7 285
Circle -16777216 true false 60 75 60
Circle -16777216 true false 180 75 60
Rectangle -16777216 true false 60 195 240 225

face sad
false
0
Circle -7500403 true true 8 8 285
Circle -16777216 true false 60 75 60
Circle -16777216 true false 180 75 60
Polygon -16777216 true false 150 168 90 184 62 210 47 232 67 244 90 220 109 205 150 198 192 205 210 220 227 242 251 229 236 206 212 183

fish
false
0
Polygon -1 true false 44 131 21 87 15 86 0 120 15 150 0 180 13 214 20 212 45 166
Polygon -1 true false 135 195 119 235 95 218 76 210 46 204 60 165
Polygon -1 true false 75 45 83 77 71 103 86 114 166 78 135 60
Polygon -7500403 true true 30 136 151 77 226 81 280 119 292 146 292 160 287 170 270 195 195 210 151 212 30 166
Circle -16777216 true false 215 106 30

flag
false
0
Rectangle -7500403 true true 60 15 75 300
Polygon -7500403 true true 90 150 270 90 90 30
Line -7500403 true 75 135 90 135
Line -7500403 true 75 45 90 45

flower
false
0
Polygon -10899396 true false 135 120 165 165 180 210 180 240 150 300 165 300 195 240 195 195 165 135
Circle -7500403 true true 85 132 38
Circle -7500403 true true 130 147 38
Circle -7500403 true true 192 85 38
Circle -7500403 true true 85 40 38
Circle -7500403 true true 177 40 38
Circle -7500403 true true 177 132 38
Circle -7500403 true true 70 85 38
Circle -7500403 true true 130 25 38
Circle -7500403 true true 96 51 108
Circle -16777216 true false 113 68 74
Polygon -10899396 true false 189 233 219 188 249 173 279 188 234 218
Polygon -10899396 true false 180 255 150 210 105 210 75 240 135 240

house
false
0
Rectangle -7500403 true true 45 120 255 285
Rectangle -16777216 true false 120 210 180 285
Polygon -7500403 true true 15 120 150 15 285 120
Line -16777216 false 30 120 270 120

leaf
false
0
Polygon -7500403 true true 150 210 135 195 120 210 60 210 30 195 60 180 60 165 15 135 30 120 15 105 40 104 45 90 60 90 90 105 105 120 120 120 105 60 120 60 135 30 150 15 165 30 180 60 195 60 180 120 195 120 210 105 240 90 255 90 263 104 285 105 270 120 285 135 240 165 240 180 270 195 240 210 180 210 165 195
Polygon -7500403 true true 135 195 135 240 120 255 105 255 105 285 135 285 165 240 165 195

line
true
0
Line -7500403 true 150 0 150 300

line half
true
0
Line -7500403 true 150 0 150 150

pentagon
false
0
Polygon -7500403 true true 150 15 15 120 60 285 240 285 285 120

person
false
0
Circle -7500403 true true 110 5 80
Polygon -7500403 true true 105 90 120 195 90 285 105 300 135 300 150 225 165 300 195 300 210 285 180 195 195 90
Rectangle -7500403 true true 127 79 172 94
Polygon -7500403 true true 195 90 240 150 225 180 165 105
Polygon -7500403 true true 105 90 60 150 75 180 135 105

plant
false
0
Rectangle -7500403 true true 135 90 165 300
Polygon -7500403 true true 135 255 90 210 45 195 75 255 135 285
Polygon -7500403 true true 165 255 210 210 255 195 225 255 165 285
Polygon -7500403 true true 135 180 90 135 45 120 75 180 135 210
Polygon -7500403 true true 165 180 165 210 225 180 255 120 210 135
Polygon -7500403 true true 135 105 90 60 45 45 75 105 135 135
Polygon -7500403 true true 165 105 165 135 225 105 255 45 210 60
Polygon -7500403 true true 135 90 120 45 150 15 180 45 165 90

sheep
false
0
Rectangle -7500403 true true 151 225 180 285
Rectangle -7500403 true true 47 225 75 285
Rectangle -7500403 true true 15 75 210 225
Circle -7500403 true true 135 75 150
Circle -16777216 true false 165 76 116

square
false
0
Rectangle -7500403 true true 30 30 270 270

square 2
false
0
Rectangle -7500403 true true 30 30 270 270
Rectangle -16777216 true false 60 60 240 240

star
false
0
Polygon -7500403 true true 151 1 185 108 298 108 207 175 242 282 151 216 59 282 94 175 3 108 116 108

target
false
0
Circle -7500403 true true 0 0 300
Circle -16777216 true false 30 30 240
Circle -7500403 true true 60 60 180
Circle -16777216 true false 90 90 120
Circle -7500403 true true 120 120 60

tree
false
0
Circle -7500403 true true 118 3 94
Rectangle -6459832 true false 120 195 180 300
Circle -7500403 true true 65 21 108
Circle -7500403 true true 116 41 127
Circle -7500403 true true 45 90 120
Circle -7500403 true true 104 74 152

triangle
false
0
Polygon -7500403 true true 150 30 15 255 285 255

triangle 2
false
0
Polygon -7500403 true true 150 30 15 255 285 255
Polygon -16777216 true false 151 99 225 223 75 224

truck
false
0
Rectangle -7500403 true true 4 45 195 187
Polygon -7500403 true true 296 193 296 150 259 134 244 104 208 104 207 194
Rectangle -1 true false 195 60 195 105
Polygon -16777216 true false 238 112 252 141 219 141 218 112
Circle -16777216 true false 234 174 42
Rectangle -7500403 true true 181 185 214 194
Circle -16777216 true false 144 174 42
Circle -16777216 true false 24 174 42
Circle -7500403 false true 24 174 42
Circle -7500403 false true 144 174 42
Circle -7500403 false true 234 174 42

turtle
true
0
Polygon -10899396 true false 215 204 240 233 246 254 228 266 215 252 193 210
Polygon -10899396 true false 195 90 225 75 245 75 260 89 269 108 261 124 240 105 225 105 210 105
Polygon -10899396 true false 105 90 75 75 55 75 40 89 31 108 39 124 60 105 75 105 90 105
Polygon -10899396 true false 132 85 134 64 107 51 108 17 150 2 192 18 192 52 169 65 172 87
Polygon -10899396 true false 85 204 60 233 54 254 72 266 85 252 107 210
Polygon -7500403 true true 119 75 179 75 209 101 224 135 220 225 175 261 128 261 81 224 74 135 88 99

wheel
false
0
Circle -7500403 true true 3 3 294
Circle -16777216 true false 30 30 240
Line -7500403 true 150 285 150 15
Line -7500403 true 15 150 285 150
Circle -7500403 true true 120 120 60
Line -7500403 true 216 40 79 269
Line -7500403 true 40 84 269 221
Line -7500403 true 40 216 269 79
Line -7500403 true 84 40 221 269

x
false
0
Polygon -7500403 true true 270 75 225 30 30 225 75 270
Polygon -7500403 true true 30 75 75 30 270 225 225 270

@#$#@#$#@
NetLogo 4.1.2
@#$#@#$#@
@#$#@#$#@
@#$#@#$#@
@#$#@#$#@
@#$#@#$#@
default
0.0
-0.2 0 1.0 0.0
0.0 1 1.0 0.0
0.2 0 1.0 0.0
link direction
true
0
Line -7500403 true 150 150 90 180
Line -7500403 true 150 150 210 180

@#$#@#$#@
0
@#$#@#$#@